home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / time.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  10.1 KB  |  543 lines
  1. ;
  2. ; time.s -- an ACE linked library module: time and date functions.
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 3rd-30th November, 1st-13th December 1991,
  21. ;      20th, 23rd,25th-27th January 1992, 
  22. ;         2nd,4th,6th,12th-19th,21st-24th,29th February 1992,
  23. ;      1st,14th March 1992,
  24. ;      4th,7th,21st,22nd,26th April 1992,
  25. ;      2nd,3rd,5th,7th,8th,10th-17th May 1992,
  26. ;      6th,8th,11th,12th,28th,30th June 1992,
  27. ;      1st-3rd,13th,14th,18th-20th,22nd July 1992,
  28. ;      9th August 1992,
  29. ;      5th December 1992,
  30. ;      1st March 1993,
  31. ;      19th March 1994
  32. ;
  33. ; registers d0-d6 and a0-a3 are modified by some of the following. BEWARE!
  34. ;
  35. ; a4,a5 are used by link/unlk.
  36. ; a6 is library base holder.
  37. ; a7 is stack pointer. 
  38. ; d7 is used for array index calculations.
  39. ;
  40.  
  41. ; misc. defines
  42. MAXSTRINGSIZE    EQU    1024
  43.  
  44.        ; time and date functions
  45.     xdef    _timeofday
  46.     xdef    _date
  47.     xdef    _getday
  48.     xdef    _timer
  49.     xdef    _ontimerstart
  50.      xdef    _ontimer
  51.     
  52.        ; external references 
  53.      xref    _shortfmt
  54.     xref    _longfmt
  55.  
  56.     xref    _sprintf
  57.      xref      _DOSBase
  58.     xref    _LVODateStamp    
  59.     xref    _strcat
  60.     xref    _strcpy
  61.     xref    _MathBase
  62.     xref    _LVOSPFlt
  63.     xref    _LVOSPAdd
  64.     xref    _LVOSPMul
  65.     xref    _LVOSPDiv
  66.     xref    _LVOSPCmp
  67.     
  68.     SECTION time_code,CODE
  69.  
  70. ;*** TIME and DATE FUNCTIONS ***
  71.  
  72. ;
  73. ; TIME$ - returns a pointer to a string containing the time in hh:mm:ss format
  74. ;      in d0.
  75. ;
  76. _timeofday:
  77.     move.l    #_datestampholder,d1
  78.     movea.l    _DOSBase,a6
  79.     jsr    _LVODateStamp(a6)
  80.     lea    _datestampholder,a1
  81.  
  82.     move.l    4(a1),d0
  83.     divu    #60,d0
  84.     move.w    d0,_todhrs        ; hours = 0..23
  85.  
  86.     swap    d0
  87.     move.w    d0,_todmins        ; minutes = 0..59
  88.  
  89.     move.l    8(a1),d0
  90.     divu    #50,d0
  91.     move.w    d0,_todsecs        ; seconds = 0..59
  92.  
  93.     move.w    _todhrs,-(sp)
  94.     pea    _shortfmt
  95.     pea    _todhrstr
  96.     jsr    _sprintf
  97.     add.l    #10,sp            ; hours to string
  98.  
  99.     move.w    _todmins,-(sp)
  100.     pea    _shortfmt
  101.     pea    _todminstr
  102.     jsr    _sprintf
  103.     add.l    #10,sp            ; minutes to string
  104.  
  105.     move.w    _todsecs,-(sp)
  106.     pea    _shortfmt
  107.     pea    _todsecstr
  108.     jsr    _sprintf
  109.     add.l    #10,sp            ; seconds to string
  110.  
  111.     lea    _tmpstring,a2
  112.     move.b    #0,(a2)        ; EOS for _strcat
  113.  
  114.     cmpi.w    #10,_todhrs
  115.     bge.s    _concathrs
  116.     lea    _zerostr,a1
  117.     movea.l    a2,a0        
  118.     jsr    _strcat            ; concatenate hours to tod string
  119. _concathrs:
  120.     lea    _todhrstr,a1
  121.     movea.l    a2,a0
  122.     jsr    _strcat
  123.  
  124.     lea    _colonstr,a1
  125.     movea.l    a2,a0
  126.     jsr    _strcat            ; colon in hh:mm
  127.  
  128.     cmpi.w    #10,_todmins
  129.     bge.s    _concatmins
  130.     lea    _zerostr,a1
  131.     movea.l    a2,a0        
  132.     jsr    _strcat            ; concatenate minutes to tod string
  133. _concatmins:
  134.     lea    _todminstr,a1
  135.     movea.l    a2,a0
  136.     jsr    _strcat
  137.  
  138.     lea    _colonstr,a1
  139.     movea.l    a2,a0
  140.     jsr    _strcat            ; colon in mm:ss
  141.     
  142.     cmpi.w    #10,_todsecs
  143.     bge.s    _concatsecs
  144.     lea    _zerostr,a1
  145.     movea.l    a2,a0        
  146.     jsr    _strcat            ; concatenate seconds to tod string
  147. _concatsecs:
  148.     lea    _todsecstr,a1
  149.     movea.l    a2,a0
  150.     jsr    _strcat
  151.     
  152.     movea.l    a2,a1
  153.     lea    _timestring,a0
  154.     jsr    _strcpy            ; copy temp string to tod string
  155.  
  156.     move.l    #_timestring,d0        ; address in d0
  157.  
  158.     rts
  159.  
  160. ;
  161. ; DATE$ - returns pointer to a string containing the date in mm-dd-yyyy format
  162. ;       in d0. See rwm.c year_and_month() function.
  163. ;
  164. _date:
  165.     ; initialise year, month and day of week
  166.       move.l    #1978,_year
  167.     move.l    #1,_month
  168.     move.l    #0,_day_of_week
  169.  
  170.     ; get days
  171.     move.l    #_datestampholder,d1
  172.     movea.l    _DOSBase,a6
  173.     jsr    _LVODateStamp(a6)
  174.     lea    _datestampholder,a1
  175.     move.l    (a1),_days
  176.  
  177.     ; find the year
  178. _find_year:
  179.     cmpi.l    #365,_days
  180.     ble    _modify_feb    ; days > 365? -> continue finding year
  181.     
  182.     ; leap year?
  183.     move.l    _year,d0
  184.     jsr    _leap_year_check
  185.     cmpi.b    #0,d0
  186.     beq.s    _no_leap_year
  187.  
  188.     ; decrement days by 366
  189.     subi.l    #366,_days
  190.  
  191.     ; update day of week
  192.     move.l    #366,d1
  193.     jsr    _change_day_of_week
  194.  
  195.     ; increment year
  196.     addi.l    #1,_year
  197.     bra    _find_year
  198.     
  199.  _no_leap_year:
  200.     ; decrement days by 365
  201.     subi.l    #365,_days
  202.  
  203.     ; update day of week
  204.     move.l    #365,d1
  205.     jsr    _change_day_of_week
  206.     
  207.     ; increment year
  208.     addi.l    #1,_year
  209.     bra    _find_year
  210.  
  211.     ; calculate month
  212. _modify_feb:
  213.     ; get address of february day holder
  214.     move.l    #_days_in_month,d0
  215.     add.l    #2,d0
  216.     move.l    d0,a0
  217.  
  218.     ; default is 28 days
  219.     move.w    #28,(a0)
  220.  
  221.     ; leap year?
  222.     move.l    _year,d0
  223.     jsr    _leap_year_check
  224.     cmpi.b    #0,d0
  225.     beq.s    _find_month
  226.  
  227.     ; add a leap day
  228.     move.w    #29,(a0)
  229.  
  230. _find_month:
  231.     jsr    _days_in_this_month
  232.     move.l    _days,d1
  233.     cmp.l    d0,d1        ; days (d1) > days in this month (d0) ?
  234.     ble.s    _adjust_day_and_month
  235.  
  236.     ; decrement # of days
  237.     jsr    _days_in_this_month
  238.     sub.l    d0,_days    ; days -= days in this month
  239.     
  240.     ; update day of week
  241.     move.l    d0,d1        ; d1 = days in this month
  242.     jsr    _change_day_of_week
  243.  
  244.     ; increment month
  245.     addi.l    #1,_month    ; month++
  246.     bra.s    _find_month
  247.  
  248. _adjust_day_and_month:
  249.     ; final day of week update
  250.     move.l    _days,d1
  251.     jsr    _change_day_of_week
  252.  
  253.     cmpi.l    #2000,_year    ; year < 2000?
  254.     bge.s    _adjust_day_month
  255.     addi.l    #1,_days    ; days++
  256.  
  257. _adjust_day_month:
  258.     jsr    _days_in_this_month
  259.     move.l    _days,d1
  260.     cmp.l    d0,d1        ; days (d1) > days in this month (d0) ?
  261.     ble.s    _adjust_month_and_year
  262.     move.l    #1,_days    ; days=1
  263.     addi.l    #1,_month    ; month++
  264.  
  265. _adjust_month_and_year:
  266.     cmpi.l    #13,_month    ; month=13 ?
  267.     bne.s    _construct_datestring
  268.     move.l    #1,_month    ; month=1
  269.     addi.l    #1,_year    ; year++
  270.  
  271. _construct_datestring:
  272.     ; convert days,month,year to strings
  273.     move.l    #_daystr,d1
  274.     cmpi.l    #10,_days    ; days < 10?
  275.     bge.s    _makedaystring
  276.     ; '0' prefix
  277.     move.l    d1,a0
  278.     move.b    #48,(a0)
  279.     add.l    #1,d1        ; add 1 to start posn in day string
  280.  
  281. _makedaystring:
  282.     move.l    _days,-(sp)
  283.     pea    _longfmt
  284.     move.l    d1,-(sp)    ; address of day string
  285.     jsr    _sprintf
  286.     add.l    #12,sp
  287.  
  288.     ; month string (as for days)
  289.     move.l    #_monthstr,d1
  290.     cmpi.l    #10,_month    ; month < 10 ?
  291.     bge.s    _makemonthstring
  292.     ; '0' prefix
  293.     move.l    d1,a0
  294.     move.b    #48,(a0)
  295.     add.l    #1,d1
  296.  
  297. _makemonthstring:
  298.     move.l    _month,-(sp)
  299.     pea    _longfmt
  300.     move.l    d1,-(sp)
  301.     jsr    _sprintf
  302.     add.l    #12,sp
  303.  
  304.     ; year string
  305.     move.l    _year,-(sp)
  306.     pea    _longfmt
  307.     pea    _yearstr
  308.     jsr    _sprintf
  309.     add.l    #12,sp
  310.  
  311.     ; build whole date string
  312.     lea    _tmpstring,a0
  313.     move.b    #0,(a0)        ; EOS for _strcat
  314.  
  315.     ; month
  316.     lea    _tmpstring,a0
  317.     lea    _monthstr,a1
  318.     jsr    _strcat        ; MM
  319.  
  320.     lea    _tmpstring,a0
  321.     lea    _dash,a1
  322.     jsr    _strcat        ; '-'
  323.  
  324.     ; day
  325.     lea    _tmpstring,a0
  326.     lea    _daystr,a1
  327.     jsr    _strcat        ; DD
  328.  
  329.     lea    _tmpstring,a0
  330.     lea    _dash,a1
  331.     jsr    _strcat        ; '-'
  332.  
  333.     ; year
  334.     lea    _tmpstring,a0
  335.     lea    _yearstr,a1
  336.     jsr    _strcat        ; YYYY
  337.  
  338.     lea    _datestring,a0
  339.     lea    _tmpstring,a1
  340.     jsr    _strcpy
  341.  
  342.     move.l    #_datestring,d0
  343.         
  344.     rts    
  345.  
  346. ;
  347. ; Leap Year? d0=year. Returns 0 or -1 in d0.
  348. ;
  349. _leap_year_check:
  350.     ; divisible by 4?
  351.     move.l    d0,d1
  352.     divu    #4,d1
  353.     swap    d1
  354.     cmpi.w    #0,d1
  355.     beq.s    _check100
  356.     bra    _quitleapyearcheck
  357.  
  358.     ; divisible by 100?
  359. _check100:
  360.     move.l    d0,d1
  361.     divu    #100,d1
  362.     swap    d1
  363.     cmpi.w    #0,d1
  364.     beq.s    _check400
  365.     move.b    #-1,d0        ; leap year
  366.     rts
  367.     
  368. _check400:
  369.     move.l    d0,d1
  370.     divu    #400,d1
  371.     swap     d1
  372.     cmpi.w    #0,d1
  373.     bne.s    _quitleapyearcheck
  374.     move.b    #-1,d0        ; leap year
  375.     rts
  376.  
  377. _quitleapyearcheck:
  378.     move.b    #0,d0        ; not a leap year
  379.     rts
  380.  
  381. ;
  382. ; Return # of days in this month.
  383. ;
  384. _days_in_this_month:
  385.     move.l    _month,d0
  386.     sub.l    #1,d0
  387.     lsl.l    #1,d0        ; index *= 2
  388.     move.l    #_days_in_month,d1
  389.     add.l    d0,d1
  390.     move.l    d1,a0
  391.     move.w    (a0),d0        ; days_in_month[month-1]
  392.     ext.l    d0        
  393.  
  394.     rts
  395.  
  396. ;
  397. ; Update the day of week to be within the range 0..6. 
  398. ;
  399. _change_day_of_week:
  400.     move.l    _day_of_week,d0
  401.     add.l    d1,d0
  402.     divu    #7,d0
  403.     swap    d0
  404.     ext.l    d0
  405.     move.l    d0,_day_of_week    
  406.     rts
  407.  
  408. ;
  409. ; Return day of week in d0 as a number from 0..6 where 0=Sunday.
  410. ; DATE$ must be called first to update _day_of_week variable.
  411. ;
  412. _getday:
  413.     move.l    _day_of_week,d0
  414.     rts
  415.  
  416. ;
  417. ; TIMER - returns a single-precision value in d0 corresponding to seconds 
  418. ;         elapsed since midnight. 
  419. ;
  420. _timer:
  421.     move.l    #_datestampholder,d1
  422.     movea.l    _DOSBase,a6
  423.     jsr    _LVODateStamp(a6)
  424.     lea    _datestampholder,a1            
  425.  
  426.     movea.l    _MathBase,a6
  427.  
  428.     move.l    4(a1),d0        
  429.     jsr    _LVOSPFlt(a6)        
  430.     move.l    d0,_mins        ; minutes since midnight
  431.  
  432.     move.l    8(a1),d0
  433.     jsr    _LVOSPFlt(a6)
  434.     move.l    d0,_ticks        ; ticks in current minute
  435.  
  436.     move.l    _mins,d0        
  437.     move.l    #$f0000046,d1        ; ffp 60
  438.     jsr    _LVOSPMul(a6)        ; seconds since midnight (_mins*60)
  439.     move.l    d0,_minsecs
  440.  
  441.     move.l    _ticks,d0        
  442.     move.l    #$c8000046,d1        ; ffp 50 (50 ticks per sec)
  443.     jsr    _LVOSPDiv(a6)        ; seconds in current minute (_ticks/50)
  444.     move.l    d0,_ticksecs
  445.     
  446.     move.l    _minsecs,d0
  447.     move.l    _ticksecs,d1
  448.     jsr    _LVOSPAdd(a6)        ; total seconds elapsed since
  449.                     ; midnight including current minute
  450.     rts
  451.             
  452. ;
  453. ; Initialises timer event trapping with a start time. 
  454. ;
  455. _ontimerstart:
  456.     jsr    _timer
  457.     move.l    d0,_last_time    
  458.     rts
  459.  
  460. ;
  461. ; Determines whether a timer event is due. d0=timer event interval.
  462. ; A boolean result is returned in d0. 
  463. ;
  464. _ontimer:
  465.     ; calculate target time
  466.     movea.l    _MathBase,a6
  467.     move.l    _last_time,d1
  468.     jsr    _LVOSPAdd(a6)
  469.     move.l    d0,_target_time    ; target_time = last_time + interval
  470.  
  471.     ; get current time
  472.     jsr    _timer    
  473.     move.l    d0,_curr_time    ; store current time
  474.  
  475.     ; is an event due?
  476.     movea.l    _MathBase,a6
  477.     move.l    _target_time,d1    
  478.     jsr    _LVOSPCmp(a6)    ; curr_time (d0) >= target_time (d1)?
  479.     bge.s    _target_time_reached
  480.  
  481.     moveq    #0,d0        ; timer event NOT due
  482.     rts
  483.  
  484. _target_time_reached:
  485.     ; update last time an event occurred
  486.     move.l    _curr_time,_last_time
  487.  
  488.     moveq    #-1,d0        ; timer event due
  489.     rts
  490.  
  491. ;*****************************
  492.  
  493.     SECTION time_data,DATA
  494.  
  495. ; * general *
  496. _zerostr:    dc.b '0',0
  497. _colonstr:    dc.b ':',0
  498.  
  499. ; * date *
  500. _dash:         dc.b '-',0
  501. _days_in_month: dc.w 31,28,31,30,31,30,31,31,30,31,30,31
  502.  
  503. ; *************************
  504.  
  505.     SECTION time_mem,BSS
  506.  
  507. ; * general *
  508. _tmpstring:            ds.b MAXSTRINGSIZE
  509. _datestampholder:    ds.l 3
  510.  
  511. ; * timeofday *
  512. _tmpaddr:        ds.l 1
  513. _todhrs:        ds.w 1
  514. _todmins:        ds.w 1
  515. _todsecs:        ds.w 1
  516. _todhrstr:        ds.b 3
  517. _todminstr:        ds.b 3
  518. _todsecstr:        ds.b 3
  519. _timestring:        ds.b 9
  520.  
  521. ; * date *
  522. _days:            ds.l 1
  523. _month:            ds.l 1
  524. _year:            ds.l 1
  525. _daystr:        ds.b 3
  526. _monthstr:        ds.b 3
  527. _yearstr:        ds.b 5
  528. _datestring:        ds.b 11
  529. _day_of_week:        ds.l 1
  530.  
  531. ; * timer *
  532. _mins:            ds.l 1
  533. _ticks:            ds.l 1
  534. _minsecs:        ds.l 1
  535. _ticksecs:        ds.l 1
  536.  
  537. ; * ontimer *
  538. _last_time:        ds.l 1
  539. _curr_time:        ds.l 1
  540. _target_time:        ds.l 1
  541.  
  542.     END
  543.